lexonomy_formatting/view.xsl

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html"/>
    
    <xsl:template match="clanek">
        <div style="font-family: Verdana, sans-serif; font-size: 1rem; line-height: 1.5em;">
            <xsl:apply-templates/>
        </div>
    </xsl:template>

    <xsl:template match="glava">
        <div>
            <xsl:apply-templates/>
        </div>
    </xsl:template>

    <xsl:template match="iztocnica">
        <xsl:text xml:space="preserve"> </xsl:text>
        <span style="font-size: 1.15em; color: #cc3366; font-weight: bold;">
            <xsl:apply-templates/>
        </span>
        <xsl:text xml:space="preserve"> </xsl:text>
    </xsl:template>

    <xsl:template match="besedna_vrsta">
        <xsl:text xml:space="preserve"> </xsl:text>
        <span style="color: #666666; font-style: italic;">
            <xsl:apply-templates/>
        </span>
        <xsl:text xml:space="preserve"> </xsl:text>
    </xsl:template>
    
    <xsl:template match="oblika"><xsl:apply-templates/></xsl:template>
    <xsl:template match="zaglavje"><xsl:apply-templates/></xsl:template>
    <xsl:template match="zapis"/>
    <xsl:template match="korpusi"/>
    <xsl:template match="korpus"/>
    <xsl:template match="frek_lema"/>
    <xsl:template match="opombe"/>
    
    <xsl:template match="geslo"><xsl:apply-templates/></xsl:template>

    <xsl:template match="pomen">
        <div style="border-top: 1px dotted #999999; padding-top: 0.5em; margin-top: 0.5em;">
            <div style="float: left; margin-left: 0.5em; color: #999999; font-weight: bold;">
                <xsl:choose>
                    <xsl:when test="count(../pomen)&gt;1">
                        <xsl:value-of select="position()"/>
                    </xsl:when>
                    <xsl:otherwise>
                        •
                    </xsl:otherwise>
                </xsl:choose>
            </div>
            <div style="margin-left: 2em;">
                <xsl:apply-templates select="podpomen | indikator | oznaka | pomenska_shema"/>
                <xsl:choose>
                    <xsl:when test="count(../pomen)&gt;1 and (skladenjske_skupine//text() | skladenjske_zveze//text() | stalne_zveze//text() | frazeoloske_zveze//text())">
                        <div style="padding: 0.5em 0;">
                            <a class="morelessbutton" style="" href="javascript:void(null)" onclick="$(this).parent().parent().find('.hidden').first().slideToggle(); $(this).parent().find('a').toggle();">▼ more</a>
                            <a class="morelessbutton" style="display: none;" href="javascript:void(null)" onclick="$(this).parent().parent().find('.hidden').first().slideToggle(); $(this).parent().find('a').toggle();">▲ less</a>
                        </div>
                        <div class="hidden" style="display: none">
                            <xsl:apply-templates select="skladenjske_skupine | skladenjske_zveze | stalne_zveze | frazeoloske_zveze"/>
                        </div>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:apply-templates select="skladenjske_skupine | skladenjske_zveze | stalne_zveze | frazeoloske_zveze"/>
                    </xsl:otherwise>
                </xsl:choose>
            </div>
            <div style="clear: left;"></div>
        </div>
    </xsl:template>
    
    <xsl:template match="stalne_zveze[not(ancestor::pomen)] | frazeoloske_zveze[not(ancestor::pomen)]">
        <div style="border-top: 1px dotted #999999; padding-top: 0.5em; margin-top: 0.5em;">
            <xsl:apply-templates/>
        </div>
    </xsl:template>

    <xsl:template match="stalne_zveze[ancestor::pomen] | frazeoloske_zveze[ancestor::pomen]">
        <div style="margin: 0.5em 0;">
            <xsl:apply-templates/>
        </div>
    </xsl:template>

    <xsl:template match="podpomen">
        <div style="margin-bottom: 0.5em;">
            <xsl:apply-templates/>
        </div>
    </xsl:template>

    <xsl:template match="skladenjska_struktura | skladenjska_zveza">
        <div style="margin: 0.5em 0; border-left: 8px solid #eeeeee; padding: 0 0 0 0.75em;">
            <xsl:apply-templates/>
        </div>
    </xsl:template>

    <xsl:template match="frazeoloska_enota | stalna_zveza">
        <div>
            <xsl:apply-templates/>
        </div>
    </xsl:template>
    
    <xsl:template match="kolokacija | r_kolokacija | skladenjska_zveza//zveza">
        <xsl:text xml:space="preserve"> </xsl:text>
        <span style="color: #cc3366;">
            <xsl:apply-templates/>
        </span>
        <xsl:text xml:space="preserve"> </xsl:text>
    </xsl:template>
    
    <xsl:template match="kolokacije//p | kolokacije//i">
        <xsl:text xml:space="preserve"> </xsl:text>
        <xsl:apply-templates/>
    </xsl:template>
    

    <xsl:template match="kolokacije//ks">
        <xsl:text xml:space="preserve"> (</xsl:text>
        <xsl:apply-templates/>
        <xsl:text xml:space="preserve">) </xsl:text>
    </xsl:template>
    
    <xsl:template match="k[not(position()=last())]">
        <xsl:apply-templates/>
        <xsl:text xml:space="preserve">, </xsl:text>
    </xsl:template>
    
    <xsl:template match="enota | stalna_zveza//zveza">
        <xsl:text xml:space="preserve"> </xsl:text>
        <span style="color: #cc3366; font-weight: bold;">
            <xsl:apply-templates/>
        </span>
        <xsl:text xml:space="preserve"> </xsl:text>
    </xsl:template>
    
    <xsl:template match="indikator | oznaka">
        <xsl:text xml:space="preserve"> </xsl:text>
        <span style="color: #999999; font-style: italic; text-transform: uppercase">
            <xsl:apply-templates/>
        </span>
        <xsl:text xml:space="preserve"> </xsl:text>
    </xsl:template>
    
    <xsl:template match="pomenska_shema"/>
    <xsl:template match="definicija1"/>
    <xsl:template match="definicija2"/>
    
    <xsl:template match="struktura"/>
    <xsl:template match="vzorec"/>
    
   <xsl:template match="zgledi">
        <div style="margin: 0.5em 0;">
            <xsl:apply-templates/>
        </div>
    </xsl:template>
   <xsl:template match="vecjez[zgled]">
        <div>
            <div style="float: left; margin-left: 0.5em; color: #999999; font-weight: bold;">
                »
            </div>
            <div style="margin-left: 2em;">
                <xsl:apply-templates/>
            </div>
            <div style="clear: left;"></div>
        </div>
    </xsl:template>
    <xsl:template match="vecjez[zgled] | zgled[not(parent::vecjez)]">
        <div>
            <div style="float: left; margin-left: 0.5em; color: #999999; font-weight: bold;">
                »
            </div>
            <div style="margin-left: 2em;">
                <span style="color: #666666; font-weight: bold;">
                    <xsl:apply-templates/>
                </span>
            </div>
            <div style="clear: left;"></div>
        </div>
    </xsl:template>
     <xsl:template match="zgled//*">
        <xsl:text xml:space="preserve"> </xsl:text>
        <xsl:apply-templates/>
        <xsl:text xml:space="preserve"> </xsl:text>
    </xsl:template>
     
    
    
  </xsl:stylesheet>